Win32ASM学习[14]:符号扩展指令: CBW,CWDE,CDQ,CWD

-----------------------------------------------------------------------------------------------------------------------------------------------------------------

;CBW(Convert Byte to Word):      将 AL 扩展为 AX

;CWDE(Convert Word to Extended Double): 将 AX 扩展为 EAX

;CDQ(Convert Doubleword to Quadword): 将 EAX 扩展为 64 位数 EDX:EAX

;CWD(Convert Word to Doubleword):  将 AX 扩展为 DX:AX

;它们都是用符号位填充多出的空间;它们对 EFLAGS 无影响, 也无参数

-----------------------------------------------------------------------------------------------------------------------------------------------------------------

.code
main proc
    ;CBW
    mov al, 7Fh
    cbw
    PrintHex ax ;007F
   
    mov al, 80h
    cbw
    PrintHex ax ;FF80
   
    ;CWDE
    mov ax, 7FFFh
    PrintDec ax ;32767
    cwde
    PrintHex eax ;00007FFF
    PrintDec eax ;32767
   
    mov ax, 8000h
    PrintDec ax   ;-32768
    cwde
    PrintHex eax ;FFFF8000
    PrintDec eax ;-32768
   
    ;CDQ
    mov eax, 7FFFFFFFh
    cdq
    PrintHex edx ;00000000
    PrintHex eax ;7FFFFFFF
   
    mov eax, 80000000h
    cdq
    PrintHex edx ;FFFFFFFF
    PrintHex eax ;80000000
   
    ;CWD
    mov ax, 7FFFh
    cwd
    PrintHex dx ;0000
    PrintHex ax ;7FFF
   
    mov ax, 8000h
    cwd
    PrintHex dx ;FFFF
    PrintHex ax ;8000
    ret
main endp
end main

嗯  看见没  符号数的存储   数据的存储方式

main proc
    mov al, 68
    cbw
    PrintHex ax ;0044
    PrintDec ax ;68
   
    mov al, -68
    cbw
    PrintHex ax ;FFBC
    PrintDec ax ;-68
    ret
main endp
end main

-----------------------------------------------------------------------------------------------------------------------------------------------------------------

.386
.model flat, stdcall

include    windows.inc
include    kernel32.inc
include    masm32.inc
include    debug.inc
includelib kernel32.lib
includelib masm32.lib
includelib debug.lib

.code
main proc
    ;CBW 等价于 movsx ax, al
    mov al, 80h
    cbw
    PrintHex ax ;FF80
   
    mov al, 80h
    movsx ax, al
    PrintHex ax ;FF80
   
    ;CWDE 等价于 movsx eax, ax
    mov ax, 8000h
    cwde
    PrintHex eax ;FFFF8000
   
    mov ax, 8000h
    movsx eax, ax
    PrintHex eax ;FFFF8000
    ret
main endp
end main

 -------------------------------------------------------------------------------------------------------------------

 

创作挑战赛新人创作奖励来咯，坚持创作打卡瓜分现金大奖

总结

以上是生活随笔为你收集整理的Win32ASM学习[14]:符号扩展指令: CBW,CWDE,CDQ,CWD的全部内容，希望文章能够帮你解决所遇到的问题。

如果觉得生活随笔网站内容还不错，欢迎将生活随笔推荐给好友。